ASP ile Twitter İşlemleri 2

ASP Alper Dereli tarafından 22 Eylül 2009 tarihinde yazıldı.

Twitter ile ilgili ilk yazının konusu Twitter’daki takip ettiğimiz kişi sayısını bulmaktı. Bu yazıda ise bir kişinin yazdığı son 5 yazının nasıl alındığını göreceğiz.

Bu örnekte ilkinden farklı olarak fazladan iki fonksiyon kullanmam gerekti. İlk fonksiyon alacağımız tarih değerlerini anlaşılır hale getirmek için, ikinci fonksiyon ise statünün içinde bulunan linkleri tıklanabilir hale getirmek için kullanılıyor.

<%
Function TarihCevir(tarih)
	TarihDizi = Split(tarih," ")
	TarihCevir = TarihDizi(2) & " " & TarihDizi(1) & " " & TarihDizi(5) & " " & TarihDizi(3)
End Function
 
Function LinkYap(metin)
	yer1 = Instr(metin,"http://")
	If yer1 > 0 Then
		yer2 = Instr(yer1,metin," ")
		If yer2 = 0 Then yer2 = Len(metin)+1
		link = Mid(metin,yer1,yer2-yer1)
		LinkYap = Replace(metin,link,"<a href="&link&">"&link&"</a>")
	Else
		LinkYap = metin
	End If
End Function
%>

Formdan gelen kişi adı değeri varsa XMLDOM nesnemizi oluşturup verileri çekiyoruz. Bu işlem sırasında yine ilk örnekteki gibi SelectSingleNode kullanıyoruz ve kişinin yazdığı statüleri, bunları nereden ve ne zaman yazdığı bilgilerini çekiyoruz.

<%
If t <> "" Then
	Set objXML = Server.CreateObject("Microsoft.XMLDOM")   
	objXML.async = false
	objXML.setProperty "ServerHTTPRequest", true
	xmlFile = "http://twitter.com/statuses/user_timeline.xml?screen_name="&t&"&count=5"
	objXML.Load xmlFile
	Set objItems = objXML.getElementsByTagName("status")
	TwitSayisi = Int(objItems.Length)
	If TwitSayisi > 0 Then
%>
<table border="0" cellpadding="5" cellspacing="0" class="twitter">
<tr>
	<th style="width:250px;">Twit</th>
	<th style="width:100px;">Kaynak</th>
	<th style="width:150px; text-align:right">Tarih</th>
</tr>
<%
		i = 1
		For Each objItem in objItems
			text = objItem.selectSingleNode("text").Text
			kaynak = objItem.selectSingleNode("source").Text
			tarih = objItem.selectSingleNode("created_at").Text
%>
<tr <%If i mod 2 = 0 Then%> style="background:#eee;"<%End If%>>
	<td><%=LinkYap(text)%></td>
	<td><%=kaynak%></td>
	<td align="right"><%=TarihCevir(tarih)%></td>
</tr>
<%
			i = i + 1
		Next
%>
</table>
	<% End If %>
<% End If %>